mirror of
https://github.com/tormozit/RDT1C.git
synced 2025-12-17 05:04:11 +00:00
4490e1afee
+Добавлена колонка "Функциональные опции"
Общее
+Для списка значений функциональных опций сделана специализированная форма с возможностью перехода к месту хранения значения
*Реализована очистка свойства ДополнительныеСвойства объекта БД при включенном флажке "Запись на сервере" при ошибке его сериализации перед передачей его между клиентом и сервером
Форма выбора объекта метаданных
*Исправлено переналожение фильтра при смене режима "имя/представление"
Консоль заданий
+Добавлены автоконтекстные меню для списков регламентных и фоновых заданий
Загрузка табличных данных
*Улучшена работа кнопки Применить - при пустой таблице значений выполняется конвертация
*Исправлена ошибка в портативном варианте при использовании алгоритмов
Поиск дублей и замена ссылок
*Исправлена проблема не выполнения замены в константах
+Добавлена поддержка режима "События на сервере"
135 lines
7.0 KiB
Plaintext
135 lines
7.0 KiB
Plaintext
Перем _Тип Экспорт;
|
||
|
||
Процедура Конструктор(Объект) Экспорт
|
||
|
||
ЭтотОбъект.ДополнительныеСвойства = Объект.ДополнительныеСвойства;
|
||
ЭтотОбъект.ОбменДанными = ирОбщий.СтруктураОбменаДаннымиОбъектаЛкс(Объект);
|
||
ЭтотОбъект._Тип = ТипЗнч(Объект);
|
||
ОбъектМД = Объект.Метаданные();
|
||
ПоляТаблицыБД = ирОбщий.ПолучитьПоляТаблицыМДЛкс(ОбъектМД,,,, Ложь);
|
||
Данные = Новый Структура;
|
||
ПоляШапки = Новый Массив;
|
||
Для Каждого СтрокаПоля Из ПоляТаблицыБД Цикл
|
||
Данные.Вставить(СтрокаПоля.Имя);
|
||
КонецЦикла;
|
||
ЗаполнитьЗначенияСвойств(Данные, Объект);
|
||
ЭтотОбъект.Данные = Данные;
|
||
|
||
КонецПроцедуры
|
||
|
||
Функция Снимок() Экспорт
|
||
|
||
СтруктураОбъекта = Новый Структура;
|
||
СтруктураОбъекта.Вставить("ОбменДанными", ОбменДанными);
|
||
СтруктураОбъекта.Вставить("ДополнительныеСвойства", ДополнительныеСвойства);
|
||
СтруктураОбъекта.Вставить("Данные", Данные);
|
||
СтруктураОбъекта.Вставить("_Тип", _Тип);
|
||
ЗаписьXML = Новый ЗаписьXML;
|
||
ЗаписьXML.УстановитьСтроку();
|
||
Попытка
|
||
СериализаторXDTO.ЗаписатьXML(ЗаписьXML, СтруктураОбъекта, НазначениеТипаXML.Явное);
|
||
Исключение
|
||
// Убираем неудобные типы значений из дополнительных свойств объекта http://devtool1c.ucoz.ru/forum/2-832-1#3587
|
||
СтруктураОбъекта.Вставить("ДополнительныеСвойства"); // Криво
|
||
СериализаторXDTO.ЗаписатьXML(ЗаписьXML, СтруктураОбъекта, НазначениеТипаXML.Явное);
|
||
КонецПопытки;
|
||
Результат = ЗаписьXML.Закрыть();
|
||
Возврат Результат;
|
||
|
||
КонецФункции
|
||
|
||
Процедура ЗагрузитьСнимок(Снимок) Экспорт
|
||
|
||
ЧтениеXML = Новый ЧтениеXML;
|
||
ЧтениеXML.УстановитьСтроку(Снимок);
|
||
СтруктураОбъекта = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
|
||
ЧтениеXML.Закрыть();
|
||
ЗаполнитьЗначенияСвойств(ЭтотОбъект, СтруктураОбъекта,, "Данные");
|
||
Если Данные <> Неопределено Тогда
|
||
Данные.Очистить();
|
||
ирОбщий.СкопироватьУниверсальнуюКоллекциюЛкс(СтруктураОбъекта.Данные, Данные);
|
||
Иначе
|
||
ЭтотОбъект.Данные = СтруктураОбъекта.Данные;
|
||
КонецЕсли;
|
||
|
||
КонецПроцедуры
|
||
|
||
Функция КлючОбъекта()
|
||
|
||
Результат = Неопределено;
|
||
Возврат Результат;
|
||
|
||
КонецФункции
|
||
|
||
Функция ОбъектБД() Экспорт
|
||
|
||
КлючОбъекта = КлючОбъекта();
|
||
Результат = ирОбщий.ОбъектБДПоКлючуЛкс(Метаданные.НайтиПоТипу(_Тип).ПолноеИмя(), КлючОбъекта,, Ложь).Данные;
|
||
ирОбщий.СкопироватьУниверсальнуюКоллекциюЛкс(ДополнительныеСвойства, Результат.ДополнительныеСвойства);
|
||
ирОбщий.ВосстановитьСтруктуруОбменаДаннымиОбъектаЛкс(Результат, ОбменДанными);
|
||
ЗаполнитьЗначенияСвойств(Результат, Данные);
|
||
Возврат Результат;
|
||
|
||
КонецФункции
|
||
|
||
Процедура Прочитать(НаСервере = Истина) Экспорт
|
||
|
||
Если НаСервере Тогда
|
||
Снимок = Снимок();
|
||
ирСервер.ПрочитатьОбъектЧерезИмитаторЛкс(Снимок, ТипЗнч(ЭтотОбъект));
|
||
ЗагрузитьСнимок(Снимок);
|
||
Иначе
|
||
ОбъектБД = ОбъектБД();
|
||
ОбъектБД.Прочитать();
|
||
Конструктор(ОбъектБД);
|
||
КонецЕсли;
|
||
|
||
КонецПроцедуры
|
||
|
||
Функция Записать() Экспорт
|
||
|
||
#Если Не Сервер Тогда
|
||
Снимок = Снимок();
|
||
ирСервер.ЗаписатьОбъектXMLЛкс(Снимок,,,,,, ТипЗнч(ЭтотОбъект));
|
||
ЗагрузитьСнимок(Снимок);
|
||
#Иначе
|
||
ОбъектБД = ОбъектБД();
|
||
ОбъектБД.Записать();
|
||
Конструктор(ОбъектБД);
|
||
#КонецЕсли
|
||
|
||
КонецФункции
|
||
|
||
Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)
|
||
|
||
ОбъектБД = ОбъектБД();
|
||
Отказ = Не ОбъектБД.ПроверитьЗаполнение();
|
||
Конструктор(ОбъектБД);
|
||
|
||
КонецПроцедуры
|
||
|
||
Функция ДанныеВСтрокуXMLЧерезXDTO(Знач ИспользоватьXDTO = Истина, ВызыватьИсключение = Истина) Экспорт
|
||
|
||
#Если Не Сервер Тогда
|
||
Снимок = Снимок();
|
||
Результат = ирСервер.ОбъектБДИзИмитатораВСтрокуXMLЛкс(Снимок, ТипЗнч(ЭтотОбъект), ИспользоватьXDTO, ВызыватьИсключение);
|
||
#Иначе
|
||
ОбъектБД = ОбъектБД();
|
||
Результат = ирОбщий.СохранитьОбъектВВидеСтрокиXMLЛкс(ОбъектБД, ИспользоватьXDTO, , ВызыватьИсключение);
|
||
#КонецЕсли
|
||
Возврат Результат;
|
||
|
||
КонецФункции
|
||
|
||
Процедура ДанныеИзСтрокиXMLЧерезXDTO(СтрокаXML, Знач ИспользоватьXDTO = Истина, СообщатьОбОшибках = Истина) Экспорт
|
||
|
||
#Если Не Сервер Тогда
|
||
Снимок = ирСервер.ОбъектБДВИмитаторИзСтрокиXML(СтрокаXML, ТипЗнч(ЭтотОбъект), ИспользоватьXDTO, СообщатьОбОшибках);
|
||
ЗагрузитьСнимок(Снимок);
|
||
#Иначе
|
||
ОбъектБД = ирОбщий.ВосстановитьОбъектИзСтрокиXMLЛкс(СтрокаXML,, ИспользоватьXDTO, СообщатьОбОшибках);
|
||
Конструктор(ОбъектБД);
|
||
#КонецЕсли
|
||
|
||
КонецПроцедуры
|